home *** CD-ROM | disk | FTP | other *** search
/ Power Programmierung / Power-Programmierung (Tewi)(1994).iso / magazine / pcmagazi / 1989 / 18 / argv.asm < prev    next >
Assembly Source File  |  1989-09-18  |  5KB  |  126 lines
  1.  
  2.         title   ARGV --- get address of command line argument
  3.         page    55,132
  4.         .386
  5.  
  6. ; ARGV.ASM:     Return address and length of specified 
  7. ;               command line argument or fully qualified 
  8. ;               program name.  Treats blanks and tabs 
  9. ;               as whitespace.
  10. ;
  11. ; 80386 version for Phar Lap DOS|Extender
  12. ; Copyright (C) 1989 Ziff Communications Co.
  13. ; PC Magazine * Ray Duncan
  14. ; 
  15. ; Call with:    EAX    = argument number (0 based)
  16. ;
  17. ; Returns:      ES:EBX = argument address
  18. ;               EAX    = argument length (0=no argument)
  19. ;
  20. ; Uses:         nothing (other registers preserved)
  21. ;
  22. ; Note: if called with AX=0 (argv[0]), returns ES:EBX 
  23. ; pointing to fully qualified program name in environment 
  24. ; block and EAX=length.
  25. ;
  26. ; Warning: uses "magic" Phar Lap hard-wired selectors
  27. ; to address environment and PSP.  Code will need adjustment
  28. ; for other 80386 protected-mode environments.
  29.  
  30. cr      equ     0dh             ; ASCII carriage return
  31. tab     equ     09h             ; ASCII tab code
  32. blank   equ     20h             ; ASCII space code
  33.  
  34. pspsel  equ     24h             ; selector for prog seg prefix
  35. envsel  equ     2ch             ; selector for environment block
  36. cmdtail equ     80h             ; buffer for command tail
  37.  
  38. _TEXT   segment dword use32 public 'CODE'
  39.  
  40.         assume  cs:_TEXT
  41.  
  42.         public  argv
  43. argv    proc    near
  44.  
  45.         push    ecx             ; save registers
  46.         push    edi
  47.  
  48.         or      eax,eax         ; is it command tail argument 0?
  49.         jz      argv7           ; yes, jump to get program name
  50.  
  51.         mov     ebx,pspsel      ; set ES:EBX = command tail
  52.         mov     es,bx
  53.         mov     ebx,cmdtail
  54.  
  55.         xor     ah,ah           ; initialize argument counter
  56.  
  57. argv1:  mov     ecx,-1          ; set flag = outside argument
  58.  
  59. argv2:  inc     ebx             ; point to next character 
  60.         cmp     byte ptr es:[ebx],cr
  61.         je      argv6           ; exit if carriage return
  62.         cmp     byte ptr es:[ebx],blank
  63.         je      argv1           ; outside argument if ASCII blank
  64.         cmp     byte ptr es:[ebx],tab   
  65.         je      argv1           ; outside argument if ASCII tab
  66.  
  67.                                 ; not blank or tab...
  68.         jecxz   argv2           ; jump if already inside argument
  69.  
  70.         inc     ah              ; else count arguments found
  71.         cmp     ah,al           ; is this the one we're looking for?
  72.         je      argv3           ; yes, go find its length
  73.         not     ecx             ; no, set flag = inside argument
  74.         jmp     argv2           ; and look at next character
  75.  
  76. argv3:                          ; found desired argument, now
  77.                                 ; determine its length...
  78.         mov     eax,ebx         ; save param. starting address 
  79.  
  80. argv4:  inc     ebx             ; point to next character
  81.         cmp     byte ptr es:[ebx],cr
  82.         je      argv5           ; found end if carriage return
  83.         cmp     byte ptr es:[ebx],blank
  84.         je      argv5           ; found end if ASCII blank
  85.         cmp     byte ptr es:[ebx],tab   
  86.         jne     argv4           ; found end if ASCII tab
  87.  
  88. argv5:  xchg    ebx,eax         ; set ES:EBX = argument address
  89.         sub     eax,ebx         ; and EAX = argument length
  90.         jmp     argv9           ; return to caller
  91.  
  92. argv6:  xor     eax,eax         ; set EAX = 0, argument not found
  93.         jmp     argv9           ; return to caller
  94.  
  95. argv7:                          ; special handling for argv=0
  96.         mov     eax,envsel      ; get environment selector
  97.         mov     es,ax
  98.         xor     edi,edi         ; find the program name by
  99.         xor     al,al           ; first skipping over all the
  100.         mov     ecx,-1          ; environment variables...
  101.         cld
  102.  
  103. argv8:  repne scasb             ; scan for double null (can't use
  104.         scasb                   ; (SCASW since might be odd addr.)
  105.         jne     argv8           ; loop if it was a single null
  106.         add     edi,2           ; skip count word in environment
  107.         mov     ebx,edi         ; save program name address
  108.         mov     ecx,-1          ; now find its length... 
  109.         repne scasb             ; scan for another null byte
  110.         not     ecx             ; convert ECX to length 
  111.         dec     ecx
  112.         mov     eax,ecx         ; return length in EAX
  113.  
  114. argv9:                          ; common exit point
  115.         pop     edi             ; restore registers
  116.         pop     ecx
  117.         ret                     ; return to caller
  118.  
  119. argv    endp
  120.  
  121. _TEXT   ends
  122.  
  123.         end
  124.  
  125.  
  126.